Classification Attributes Including Inherited Attributes

Get the classification attributes of the classes in the DEXPI Information Model. For each class, also the inherited attributes are included.

Variables

cls
The class for which the attribute is declared, or which inherits the attribute from one of its super classes.
attribute
Name of the attribute.
rdl
The RDL reference associated with the attribute in a DEXPI-compliant Proteus file.
classification_type
Label of the classification type of the attribute. See Classification Types and Values.
is_proteus_generic_attribute
A boolean indicating if the attribute is represented as a <GenericAttribute> in a DEXPI-compliant Proteus XML file.

SPARQL Query

PREFIX meta: <http://sandbox.dexpi.org/meta/>

SELECT ?cls ?attribute ?rdl ?classification_type ?is_proteus_generic_attribute
WHERE
{
    [] a meta:ModelClass;
        meta:simpleLabel ?cls;
        meta:subClassOf* [ meta:hasDeclaration ?decl ].

    ?decl a meta:AttributeDeclaration;
        meta:hasTargetType [
            a meta:ClassificationType;
            meta:simpleLabel ?classification_type];
        meta:simpleLabel ?attribute.

    OPTIONAL
    {
        ?decl meta:rdl ?rdl.
    }

    BIND
    (
        EXISTS
        {
            ?decl meta:proteusImplementation [
                a meta:StandardGenericAttribute]
        }
        AS ?is_proteus_generic_attribute
    )
}
ORDER BY ?cls ?attribute

Partial SPARQL Results

The full query result contains 225 rows. The first rows are as follows:

cls attribute rdl classification_type is_proteus_generic_attribute
AngleBallValve HeatTracingTypeSpecialization http://sandbox.dexpi.org/rdl/HeatTracingTypeSpecialization HeatTracingTypeClassification true
AngleBallValve NumberOfPortsSpecialization http://sandbox.dexpi.org/rdl/NumberOfPortsSpecialization NumberOfPortsClassification true
AngleBallValve OnHoldSpecialization http://sandbox.dexpi.org/rdl/OnHoldSpecialization OnHoldClassification true
AngleBallValve OperationSpecialization http://sandbox.dexpi.org/rdl/OperationSpecialization OperationClassification true
AngleBallValve PipingClassArtefactSpecialization http://sandbox.dexpi.org/rdl/PipingClassArtefactSpecialization PipingClassArtefactClassification true
... ... ... ... ...

Full SPARQL Results

Cached

Note

The cached results below are guaranteed to correspond to DEXPI P&ID Specification 1.2.

Cached results:

Online

Note

Online results can change! There is no guarantee that these results correspond to DEXPI P&ID Specification 1.2.

Get results online from DEXPI SPARQL server at http://endpoint.dexpi.org: